IPアドレスの変更（batコピペ用）

NIC設定用バッチ例

コピペで使えるバッチを置いておきます。

ログはバッチファイルと同階層に「バッチファイル名+日時」.txtで出力されます。

IPv4アドレスを設定する

@echo off

rem ■set hensu
set network_name="Wi-Fi"
set ipv4-address=192.168.1.145
set subnet-mask=255.255.255.0
set gateway=192.168.1.254
set dns1=192.168.1.100
set dns2=192.168.1.254

rem ■set log time
set dt1=%date:~0,4%%date:~5,2%%date:~8,2%
set time2=%time: =0%
set tm1=%time2:~0,2%%time2:~3,2%%time2:~6,2%
set log=%~n0_[log]_%dt1%-%tm1%.txt

rem ■log header
chcp 65001
echo ###%~nx0### >>%log%
echo ###%dt1%-%tm1% >>%log%
echo. >>%log%

rem ■set ip
echo ###set ip (errorlevel) >>%log%
netsh interface ipv4 set address name=%network_name% source=static address=%ipv4-address% mask=%subnet-mask% gateway=%gateway%
echo %errorlevel% >>%log%
netsh interface ipv4 set dns name=%network_name% source=static address=%dns1% register=primary validate=no
echo %errorlevel% >>%log%
netsh interface ipv4 add dns name=%network_name% address=%dns2% index=2 validate=no
echo %errorlevel% >>%log%

rem ■show ip
echo. >>%log%
echo ###show ip >>%log%
ipconfig /all >>%log%
ipconfig /all

echo. >>%log%
echo ###END### >>%log%
pause
exit

「rem ■set hensu」項目を編集後「.bat」で保存し、実行します。

「set network_name="Wi-Fi"」はネットワーク名です。
LANケーブルの場合「"イーサネット"」で有線LANを指定できます。
ご自身のネットワーク名は「ipconfig /all」で確認してください。

DHCPを設定する